StringGrids и DBGrids с цветными ячейками смотрятся очень красиво, и Вы можете информировать пользователя о важных данных внутри Grid. Совместимость: все версии Delphi К сожалению, невозможно применить один и тот же метод к StringGrids и к DBGrids. Итак сперва рассмотрим как это сделать в StringGrid:
StringGrid
Для раскрашивания будем использовать событие "OnDrawCell". Следующий код показывает, как сделать в Grid красный бэкраунд. Бэкграунд второй колонки будет зелёным.
procedure
TForm1.StringGrid1DrawCell(Sender: TObject; ACol, ARow: Integer;
Rect: TRect; State: TGridDrawState);
const
//здесь определяем Ваш цвет. Так же можно использовать цвета по умолчанию.
clPaleGreen = TColor($CCFFCC);
clPaleRed = TColor($CCCCFF);
begin
//Если ячейка получает фокус, то нам надо закрасить её другими цветами
if (gdFocused in State) then
begin
StringGrid1.Canvas.Brush.Color := clBlack;
StringGrid1.Canvas.Font.Color := clWhite;
end
else //Если же ячейка теряет фокус, то закрашиваем её красным и зелёным
if ACol = 2 then
//Вторая колонка будет зелёной , другие - ячейки красными
StringGrid1.Canvas.Brush.color := clPaleGreen
else
StringGrid1.canvas.brush.Color := clPaleRed;
//Теперь закрасим ячейки, но только, если ячейка не Title- Row/Column
//Естественно это завит от того, есть у Вас title-Row/Columns или нет.
if (ACol > 0) and (ARow > 0) then
begin
//Закрашиваем бэкграунд
StringGrid1.Canvas.FillRect(Rect);
//Закрашиваем текст (Text). Также здесь можно добавить выравнивание и т.д..
StringGrid1.Canvas.TextOut(Rect.Left, Rect.Top, StringGrid1.Cells[ACol, ARow]);
end;
end;
|
Если Вы захотите чтобы цвет ячеек менялся в зависимости от значения в них, то можно заменить 3 линии (if Acol = 2 ......) на что-нибуть вроде этого
if StringGrid1.Cells[ACol, ARow] = 'highlight it' then
StringGrid1.Canvas.Brush.color := clPalered
else
StringGrid1.canvas.brush.Color := clWhite;
|
Ну а теперь давайте раскрасим DBGrids:
DBGrid
С DBGrids это делается намного проще. Здесь мы будем использовать событие "OnDrawColumnCell". Следующий пример разукрашивает ячейки колонки "Status" когда значение НЕ равно "a". Если Вы хотите закрасить целую линию, то достаточно удалить условие "If..." (смотрите ниже)
procedure TForm1.DBGrid1DrawColumnCell(Sender: TObject; const Rect: TRect;
DataCol: Integer; Column: TColumn; State: TGridDrawState);
const
clPaleGreen = TColor($CCFFCC);
clPaleRed = TColor($CCCCFF);
begin
if Column.FieldName = 'Status' then
//Удалите эту линию, если хотете закрасить целую линию
if Column.Field.Dataset.FieldByName('Status').AsString <> 'a' then
if (gdFocused in State) then
//имеет ли ячейка фокус?
DBGrid1.Сanvas.Brush.Color := clBlack //имеет фокус
else
DBGrid1.Сanvas.Brush.Color := clPaleGreen; //не имеет фокуса
//Теперь давайте закрасим ячейку используя стандартный метод:
DBGrid1.DefaultDrawColumnCell(Rect, DataCol, Column, State)
end;
|
Вот и всё. Не правда ли красиво?
Фрагмент кода моей программы - в зависимости от значения в поле taPlatAnswerType рисует строку белам цветом на красном фоне:
procedure TfmMain.dgPlatDrawColumnCell(Sender: TObject; const Rect:
TRect; DataCol: Integer; Column: TColumn; State: TGridDrawState);
begin
with dgPlat.Canvas do
begin
// Условие какую строку надо рисовать по другому
if (taPlatAnswerType.AsString = 'b') and not
(gdFocused in State) then
begin
Brush.Color := clRed;
Font.Color := clWhite;
FillRect(Rect);
TextOut(Rect.Left, Rect.Top, Column.Field.Text);
end
else
dgPlat.DefaultDrawColumnCell(Rect, DataCol, Column, State);
end;
end;
|
|
Цветные ячейки в StringGrid и в DBGrid